***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Jul 26, 2019                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt PZS5118BCH-AU A K
.param
+vc0 = 3.046e-12	 vc1 = 2.553e-12	 vc2 = 1		 vc3 = 8.651e-13		 vc4 = 1.7
+tc1 = 3.052e-2		 tc2 = 1.361e-2		 tc3 = 4.941e-3		 tc4 = 3.021e-2	
.func irpwr(v) {(vc0+vc1*v**vc2)*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))+(vc3*v**vc4)*(1.0+tc3*(temp-25)*exp(tc4*(temp-25)))}
d1 A K zener
g1 K A value = {irpwr(v(K,A))}
.model zener d
***** flag parameter ***
+level = 1   
***** dc model parameter ***
+ is = 5.089e-16	   n = 1.007		  rs = 1.419e-1		 ikf = 8.208e-2
+ibv = 50e-6		 nbv = 1		  bv = 18
***** capacitance parameter ***
+cjo = 5.178e-11	   m = 3.201e-1		  vj = 6.153e-1
+ fc = 0.5                      
***** temperature coefficient ***
+tnom = 25		  eg = 1.124		 xti = 3
+trs1 = -9.546e-4	tbv1 = 7.265e-4		tbv2 = -2.455e-7	tikf = 8e-3
.ends PZS5118BCH-AU
*$
